home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
The World of Computer Software
/
The World of Computer Software.iso
/
cryp.zip
/
CRYPTO.BAS
next >
Wrap
BASIC Source File
|
1988-05-28
|
2KB
|
66 lines
10 DIM A$(6),B$(6)
20 DEFINT A-Z
30 CLS:PRINT"Place file storage disk in Drive B press enter to continue"
40 INPUT GO$
50 CLS:INPUT"Is caps lock on? (Y/N)",GO$:IF GO$<>"Y" THEN 50
60 GOTO 170
70 LOCATE 1,1:PRINT SPACE$(80):LOCATE 1,1:PRINT"What name to be saved under?"
80 LOCATE 2,1:PRINT SPACE$(80):LOCATE 2,1:INPUT CRY$
90 CRY$="b:"+CRY$
100 OPEN "o",#2,CRY$
110 FOR III=1 TO 6
120 PRINT#2,A$(III)
130 PRINT#2,B$(III)
140 NEXT III
150 CLOSE #2
160 GOTO 370
170 CLS
180 LOCATE 1,1:INPUT"Do you have a saved crypto you want to recall? (Y/N)",BRING$:LOCATE 1,1:PRINT SPACE$(80)
190 IF BRING$<>"Y" THEN 230
200 LOCATE 1,1:PRINT SPACE$(80):LOCATE 1,1:INPUT "What is the name of the crypto?",CRY$
210 CRY$="b:"+CRY$
220 OPEN "i",#2,CRY$
230 FOR I=1 TO 6
240 LOCATE 1,1:PRINT "line";I;"of cryptogram";" Hit <ENTER> if no more lines"
250 IF BRING$<>"Y" THEN LOCATE 2,1:LINE INPUT"",A$(I)
260 IF BRING$="Y" THEN LINE INPUT#2,A$(I):LINE INPUT#2,B$(I)
270 IF BRING$<>"Y"THEN B$(I)=SPACE$(LEN(A$(I)))
280 IF BRING$="Y" THEN 320
290 FOR J=1 TO LEN(A$(I))
300 IF ASC(MID$(A$(I),J,1))<65 OR ASC(MID$(A$(I),J,1))>90 THEN MID$(B$(I),J,1)=MID$(A$(I),J,1)
310 NEXT J
320 LOCATE 5+(3*(I-1)),1:PRINT A$(I)
330 LOCATE 6+(3*(I-1)),1:PRINT B$(I)
340 LOCATE 2,1:PRINT SPACE$(80)
350 NEXT I
360 CLOSE #2
370 LOCATE 1,1:PRINT "1- change single letter 2- erase all 3- save 4- end"
380 LOCATE 2,1:PRINT SPACE$(80)
390 LOCATE 2,1:INPUT"",CHOICE$
400 IF ASC(CHOICE$)>64 AND ASC(CHOICE$)<91 THEN OL$=CHOICE$:GOTO 560
410 CHOICE=VAL(CHOICE$)
420 IF CHOICE=3 THEN GOTO 70
430 IF CHOICE=4 THEN END
440 IF CHOICE<>2 THEN 540
450 FOR I=1 TO 6
460 B$(I)=SPACE$(LEN(A$(I)))
470 FOR J=1 TO LEN(A$(I))
480 IF ASC(MID$(A$(I),J,1))<65 OR ASC(MID$(A$(I),J,1))>90 THEN MID$(B$(I),J,1)=MID$(A$(I),J,1)
490 NEXT J
500 LOCATE 6+(3*(I-1)),1:PRINT B$(I)
510 LOCATE 5+(3*(I-1)),1:PRINT A$(I)
520 NEXT I
530 GOTO 370
540 LOCATE 2,1:PRINT SPACE$(80):LOCATE 2,1
550 INPUT "letter to be changed ",OL$
560 LOCATE 2,40:INPUT"change to ",NL$
570 FOR I=1 TO 6
580 FOR J=1 TO LEN(A$(I))
590 IF MID$(B$(I),J,1)=NL$ THEN MID$(B$(I),J,1)=" "
600 IF MID$(A$(I),J,1)=OL$ THEN MID$(B$(I),J,1)=NL$
610 NEXT J
620 LOCATE 6+(3*(I-1)),1:PRINT B$(I)
630 LOCATE 5+(3*(I-1)),1:PRINT A$(I)
640 NEXT I
650 GOTO 370